home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh2x
/
sh20a.d64
/
listing 12
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
41 lines
10 REM * SPRITE BEISPIEL 1 *
20 REM DER HEISSLUFTBALLON
30 VIC=13*4096:REM HIER BEGINNEN DIE VIC-REGISTER
35 POKE VIC+21,1:REM EINSCHALTEN SPRITE 0
36 POKE VIC+33,14:REM HINTERGRUNDFARBE HELLBLAU
37 POKE VIC+23,1:REM SPRITE 0 IN Y VERDOPPELN
38 POKE VIC+29,1:REM UND IN X
40 POKE 2040,192:REM SPRITEZEIGER 0 AUF BLOCK 192
180 POKE VIC,100:REM X-POSITION SPRITE 0
190 POKE VIC+1,100:REM UND Y-POSITION
220 POKE VIC+39,1:REM FARBE SPRITE 0
250 FOR Y=0 TO 63
300 READ A:REM SPRITEDATEN LESEN
310 POKE 192*64+Y,A:REM UND EINTRAGEN
320 NEXT Y
330 DX=1:DY=1
340 X=PEEK(VIC):REM X-POSITION PRUEFEN
350 Y=PEEK(VIC+1):REM Y-POSITION TESTEN
360 IF Y=50 OR Y=200 THEN DY=-DY:REM BEI RANDPOSITION DY UMKEHREN
380 IF X=24 AND (PEEK(VIC+16)AND 1)=0 THEN DX=-DX:REM WENN SPRITE
390 REM AM LINKEN RAND (X<24 UND MSB=0) DANN DX UMKEHREN
400 IF X=40 AND (PEEK(VIC+16)AND 1)=1 THEN DX=-DX:REM WENN SPRITE
410 REM AM RECHTEN RAND (X=40 UND MSB=1) DANN DX UMDREHEN
420 IF X=255 AND DX=1 THEN X=-1:SIDE=1
430 REM UMSCHALTEN AUF ANDERE BILDSCHIRMSEITE
440 IF X=0 AND DX=-1 THEN X=256:SIDE=0
450 REM UMSCHALTEN AUF ANDERE BILDSCHIRMSEITE
460 X=X+DX:REM ADDIEREN VON DX ZU X
470 X=X AND 255:REM SICHERSTELLEN DASS X IM ERLAUBTEN BEREICH
480 Y=Y+DY
485 POKE VIC+16,SIDE
490 POKE VIC,X:REM NEUE X-POSITION SPRITE 0
510 POKE VIC+1,Y:REM NEUER Y-WERT
530 GOTO 340
600 REM ***** SPRITE DATEN *****
610 DATA 0,127,0,1,255,192,3,255,224,3,231,224
620 DATA 7,217,240,7,223,240,7,217,240,3,231,224
630 DATA 3,255,224,3,255,224,2,255,160,1,127,64
640 DATA 1,62,64,0,156,128,0,156,128,0,73,0,0,73,0
650 DATA 0,62,0,0,62,0,0,62,0,0,28,0,0